Theses rules draws from very simple pictures to overly complex patterns.
Code: Select all
/*-----------------------------------------
Draws more or less aesthetic
abstract pictures
-----------------------------------------*/
startshape abstract
/*-----------------------------------------
Abstract : shape or alteration
-----------------------------------------*/
rule abstract 3 { alter { } }
rule abstract { shape { } }
/*-----------------------------------------
Random alteration
-----------------------------------------*/
rule alter 3 { split { } }
rule alter { color { } }
rule alter { move { } }
rule alter { resize { } }
rule alter { turn { } }
/*-----------------------------------------
Random shape
-----------------------------------------*/
rule shape 4 { block { } }
rule shape 2 { line { } }
rule shape { worm { } }
/*-----------------------------------------
Shape : Worms
-----------------------------------------*/
rule worm { round_worm { } }
rule worm { square_worm { } }
rule round_worm {
CIRCLE { s 0.1 }
round_worm { x 0.001 r 5 }
}
rule round_worm {
CIRCLE { s 0.1 }
round_worm { x 0.001 r -5 }
}
rule round_worm 0.2 {
round_worm { s 0.9 }
}
rule round_worm 0.2 {
round_worm { s 1.11 }
}
rule round_worm 0.005 { }
rule square_worm {
SQUARE { s 0.1 }
square_worm { x 0.1 }
}
rule square_worm {
SQUARE { s 0.1 }
square_worm { y 0.1 }
}
rule square_worm {
SQUARE { s 0.1 }
square_worm { x -0.1 }
}
rule square_worm {
SQUARE { s 0.1 }
square_worm { y +0.1 }
}
rule square_worm 0.5 { }
/*-----------------------------------------
Shape : Lines
-----------------------------------------*/
rule line {
CIRCLE { s 0.1 }
round_line { x 0.05 }
}
rule line { square_line { x 0.05 } }
rule square_line 8 {
SQUARE { s 0.1 }
square_line { x 0.1 }
}
rule square_line { }
rule round_line 8 {
SQUARE { s 0.1 }
round_line { x 0.1 }
}
rule round_line {
CIRCLE { x -0.05 s 0.1 }
}
/*-----------------------------------------
Shape : Blocks
-----------------------------------------*/
rule block { square_block { } }
rule block { round_block { } }
rule square_block {
SQUARE { }
}
rule square_block {
SQUARE { }
SQUARE { s 0.9 b 1 }
}
rule round_block {
CIRCLE { }
}
rule round_block {
CIRCLE { }
CIRCLE { s 0.9 b 1 }
}
/*-----------------------------------------
Alteration : split
-----------------------------------------*/
rule split {
abstract { x -1}
abstract { x 1}
}
rule split {
abstract { y -1}
abstract { y 1}
}
rule split {
abstract { }
abstract { s 0.81 }
}
/*-----------------------------------------
Alteration : translation
-----------------------------------------*/
rule move {
abstract { x 1 }
}
rule move {
abstract { x -1 }
}
rule move {
abstract { y 1 }
}
rule move {
abstract { y -1 }
}
/*-----------------------------------------
Alteration : resize
-----------------------------------------*/
rule resize {
abstract { s 0.9 }
}
rule resize {
abstract { s 0.5 }
}
rule resize 0.01 {
abstract { s 2 }
}
rule resize 0.0001 {
abstract { s 100 }
}
/*-----------------------------------------
Alteration : rotation
-----------------------------------------*/
rule turn 2 {
abstract { r -11.25 }
}
rule turn 2 {
abstract { r 11.25 }
}
rule turn {
abstract { r 90 }
}
rule turn {
abstract { r -90 }
}
/*-----------------------------------------
Alteration : color
-----------------------------------------*/
rule color 5 {
abstract { b 0.1 }
}
rule color {
abstract { b -1 }
}
Enjoy !