Water ink
Posted: Wed Aug 17, 2005 3:32 pm
A slight variation on the previous one gives the impression of a water ink drawing.
Code: Select all
startshape composition4
background { hue 45 sat 1 b 0.9}
rule composition4 {
box {s 3}
}
rule box {
box1 {}
box2 {}
}
rule box {
box1 {s 0.9 r 10}
box2 {s 0.9 r 10}
}
rule box1 {
horizon {x 0 y 5 s 6 r -90}
horizon {x -5 y 0 s 6 r 0}
horizon {x -5 y -20 s 6 r 0}
horizon {x 20 y 5 s 6 r -90}
}
rule box2 {
horizon {x 0 y -25 s 6 r 90}
horizon {x 25 y 0 s 6 r 180}
horizon {x 25 y -20 s 6 r 180}
horizon {x 20 y -25 s 6 r 90}
}
rule horizon {
fearrow {hue 177 sat 0.5 b 1}
fearrow {|hue 177 sat 0.5 b 1 r 90}
fearrow {s 0.1 hue 177 sat 0.5 b 1 r -90}
}
//include fearrow.cfdg
//** BEGIN OF FEARROW **//
rule fearrow { fearrow1 { } }
rule fearrow { fearrow2 { } }
rule fearrow1 {
fepart { s 0.1 b 1}
fearrow1 { x 0.03 s 0.995}
}
rule fearrow2 {
fepart { s 0.2 b 1}
fearrow2 { x 0.02 s 0.995}
}
rule fearrow1 0.3 {
fearrow { }
}
rule fearrow2 0.3 {
fearrow { }
}
rule fepart {
CIRCLE { }
fepart { x -0.005 y -0.000 s 0.98 b -0.005 }
}
rule fepart {
CIRCLE { }
hair {}
fepart { x -0.005 y -0.000 s 0.97 b -0.05 }
}
rule hair {
CIRCLE { s 1 3 b 0.7 }
CIRCLE { s 1 3 b 0.7 r 45}
}
//** END OF FEARROW **//